Simple Queue Otomatis di Mikrotik dari DHCP Lease

Membuat Simple Queue Otomatis di Mikrotik dari DHCP lease – Script ini mungkin berguna untuk kalian yang memiliki user atau client pengguna internet yang banyak, sehingga kalian tidak perlu memasukan simple queue 1 per 1.

Dengan menggunakan script ini, akan otomatis membuat simple queue di Mikrotik dengan otomatis dan akan otomatis menghapus simple queue jika pengguna sudah tidak aktif atau tidak ada di list dhcp lease.

Salin script dibawah dan Anda bisa merubah bagian parentQueue, networkAddress sesuaikan dengan nama parent simple queue dan network Address yang Anda gunakan.

:local parentQueue "CLIENT_WIFI"
:local networkAddress "192.168.102.0/24"
:local mac $leaseActMAC
:local ip $leaseActIP
:local queueTag ("dhcp-" . $mac)

# pastikan parent queue ada
:if ([:len [/queue simple find where name=$parentQueue]] = 0) do={
    /queue simple add name=$parentQueue target=$networkAddress max-limit=80M/80M
}

:local host ""
:local leaseId [/ip dhcp-server lease find where active-mac-address=$mac]

:if ([:len $leaseId] > 0) do={
    :set host [/ip dhcp-server lease get $leaseId host-name]
}

:if ([:len $host] = 0) do={
    :set host "unknown"
}

:local queueName ($host . "-" . $mac)
:local qid [/queue simple find where comment=$queueTag]

:if ($leaseBound = "1") do={

    :if ([:len $qid] = 0) do={
        /queue simple add \
            name=$queueName \
            target=($ip . "/32") \
            max-limit=15M/15M \
            parent=$parentQueue \
            comment=$queueTag
    } else={
        /queue simple set $qid \
            name=$queueName \
            target=($ip . "/32") \
            max-limit=15M/15M \
            parent=$parentQueue \
            comment=$queueTag
    }

} else={

    :foreach q in=[/queue simple find where comment=$queueTag] do={
        /queue simple remove $q
    }
}

Setelah itu masuk kedalam winbox lalu pilih menu IP lalu DHCP Server, selanjutnya pilih dhcp pool yang ingin kalian masukan script.

Setelah itu pilih tab menu script dan pastekan script lalu apply dan OK.

Setelah itu dhcp lease berikutnya client yang ada di dhcp lease akan otomatis masuk kedalam simple queue. Seperti pada gambar dibawah ini.